20 OPEN15,8,15:POKE53280,6:POKE53281,6:
30 PRINT"[147]   ****   DATEI 64[146]   ****"
35 PRINT"    (C) 1985 KLAUS RACZEK"
36 PRINT"    *** MENUE[146] ***"
40 PRINT"   1[146]- KARTEI LADEN"
50 PRINT"   2[146]- KARTEI SPEICHERN"
60 PRINT"   3[146]- DATEN EINGEBEN"
70 PRINT"   4[146]- DATEN SUCHEN"
80 PRINT"   5[146]- DATEN AENDERN"
90 PRINT"   6[146]- DATEN LOESCHEN"
100 PRINT"   7[146]- MASKE ERSTELLEN"
110 PRINT"   8[146]- PROGRAMM BEENDEN"
120 PRINT"    WELCHE NUMMER ";:CH=0:INPUTCH:CH=INT(CH):POKE2,CH:IFCH=8THENEND
130 IFCH<1ORCH>7THEN30
135 IFCH=1ORCH=7THENCLR:CH=PEEK(2):OPEN15,8,15
140 ONCHGOSUB200,300,400,500,600,700,900
150 PRINT"TASTE DRUECKEN":POKE198,0:WAIT198,1:GOTO30
200 PRINT"[147]NAME DER KARTEI";:INPUTA$
205 OPEN1,8,2,A$+",S,R":GOSUB800
210 INPUT#1,FE,N,LE:DIMFE$(FE),S$(FE),DA$(LE,FE)
215 FORX=1TOFE:INPUT#1,FE$(X):NEXT
220 FORI=0TON-1:FORX=1TOFE
230 INPUT#1,DA$(I,X):NEXT:NEXT:CLOSE1:GOSUB800:RETURN
300 PRINT"[147]NAME DER KARTEI";:INPUTA$
305 OPEN1,8,2,A$+",S,W":GOSUB800
310 PRINT#1,FE:PRINT#1,N:PRINT#1,LE
315 FORX=1TOFE:PRINT#1,FE$(X)" ":NEXT
320 FORI=0TON-1:FORX=1TOFE
330 PRINT#1,DA$(I,X)" ":NEXT:NEXT
340 CLOSE1:GOSUB800:RETURN
400 PRINT"[147]DATEN EINGEBEN":L=0:FORX=1TOFE
410 PRINT""FE$(X)"[146]: ";:INPUTDA$(N,X):L=L+LEN(DA$(N,X)):NEXT
420 IFL=0THENN=N-1
430 N=N+1:RETURN
500 PRINT"[147]SUCHEN:"
505 FORI=1TOFE:PRINT""FE$(I)"[146]: ";:S$(I)="":INPUTS$(I):S(I)=LEN(S$(I)):NEXT
515 EI=0:FORX=0TON-1:FF=0:FORI=1TOFE
520 IFLEFT$(DA$(X,I),S(I))<>S$(I)THENFF=1
530 NEXT:IFFF=0GOTO560
535 NEXT:IFEI=1THENRETURN
540 PRINT"EINTRAG NICHT GEFUNDEN":RETURN
560 IFFL=1THENRETURN
565 PRINT"[147]EINTRAG GEFUNDEN:"
570 FORJ=1TOFE:PRINT""FE$(J)"[146]: "TAB(15)DA$(X,J):NEXT:EI=1
590 PRINT"TASTE DRUECKEN":POKE198,0:WAIT198,1:IFX<NGOTO535
595 RETURN
600 PRINT"[147]AENDERN:":PRINT"SUCHEN":FL=1:GOSUB505:FL=0
610 IFX>NTHENRETURN
630 FORI=1TOFE:PRINT""FE$(I)"[146]:":PRINT"  "DA$(X,I):INPUT"[145]";DA$(X,I):NEXT:RETURN
700 PRINT"[147]EINTRAG LOESCHEN":PRINT"SUCHEN":GOSUB505
710 PRINT"LOESCHEN (J/N)"
720 GETA$:IFA$=""THEN720
730 IFA$="J"THEN790
740 IFA$<>"N"THEN720
750 RETURN
790 FORI=1TOFE:DA$(X,I)=DA$(N-1,I):DA$(N-1,I)="":NEXT:N=N-1:RETURN
800 INPUT#15,A,A$:IFA=0THENRETURN
810 PRINTA$:RETURN
900 CLR:OPEN15,8,15:PRINT"[147]EINGABEMASKE ERSTELLEN:"
910 INPUT"WIEVIELE FELDER";FE
920 DIMFE$(FE),S$(FE):PRINT"NAMEN UND MITTLERE LAENGEN DER FELDER   EINGEBEN:"
930 LE=0:FORI=1TOFE:PRINTI;:INPUTFE$(I),X:LE=LE+X:NEXT
940 LE=((FRE(X)+65536)/(LE+FE*3+3)):DIMDA$(LE,FE)
950 PRINT"ES IST PLATZ FUER"INT(LE)"DATENSAETZE.":GOTO150